const
 MAXZDEPTH = $7FFFFFFF;

procedure TBitmap64.ClearZBuffer;
begin
 if (FZBuffer <> nil) then StoreDWords(FZBufferAddr, (FZBufferSize shr 2), MAXZDEPTH);
end;

procedure TBitmap64.ZPixel32(x, y, z: integer; dColor: TColorRef);
var
 zA: TAddress;

begin
 if FClipRegion.PtInRegion(x, y) then
 begin
   zA := ZAddress32(x, y);
   if (z < PInteger(zA)^) then //Всегда рисуем более ближний пиксел
   begin
     PInteger(zA)^ := z; //Новая позиция в Z-Buffer
     PDWord(PixelAddress32(x, y))^ := dColor;
   end;
 end;
end;

procedure TBitmap64.ZLine(x0, y0, z0, x1, y1, z1 : integer; dColor: TColorRef);
var
 x, y: integer;
 fX, fY, fZ: float;
 cr: TClipStruct;
 lp: integer;
 gradX, gradY, gradZ: float;
 i: integer;
 z: integer;
 dZ, dL: integer;
 w, h: integer;

begin
 //2D-отсечение
 if not ClipLine(x0, y0, x1, y1, cr) then exit;

 //Длинная сторона линии
 dL := Max(cr.W, cr.H);
 //глубина линии по Z
 dZ := Abs(z1 - z0);
 //Стартовая глубина
 z := z0;
 //Стартовая глубина для приращения
 fZ := z;

 //Шаг по Z
 if (z0 = z1) then
 begin
   gradZ := 0;
 end
 else
 if (z1 > z0) then
 begin
   //Шаг приращения Z
   gradZ := Abs(dZ / dL);
 end
 else
 if (z0 > z1) then
 begin
   //Шаг приращения Z
   gradZ := -(dZ / dL);
 end;

 //Учет последней точки
 if FDrawLastPoint then lp := 0 else lp := 1;

 x := cr.x0;
 y := cr.y0;

 //Горизонтальная линия
 if (cr.dx > cr.dy) then
 begin
   //Приращение по Y
   gradY := (cr.gradY * cr.yinc);

   //Горизонтальная ПРЯМАЯ линия
   if (gradY = 0) then
   begin
     //Выбор первой точки с которой начинается отрисовка линии
     if (cr.xinc = 1) then x := cr.x0 else x := cr.x1;

     //Цикл по ширине линии
     for i := 1 to (cr.W - lp) do
     begin
       //Точка
       ZPixel32(x, y, z, dColor);
       //Приращение X
       x := (x + cr.xinc);
       //Приращение Z
       fZ := (fZ + gradZ);
       //Целочисленный Z
       z := Round(fZ);
     end;
   end
   else
   //НЕ прямая горизонтальная линия
   begin
     //Приращение по Y
     fY := y;

     //Цикл по ширине линии
     for i := 1 to (cr.W - lp) do
     begin
       //Точка
       ZPixel32(x, y, z, dColor);
       //Приращение X
       x := (x + cr.xinc);
       //Приращение Y
       fY := (fY + gradY);
       //Приращение Z
       fZ := (fZ + gradZ);
       //Целочисленный Y
       y := Round(fY);
       //Целочисленный Z
       z := Round(fZ);
     end;
   end;
 end
 //Вертикальная линия
 else
 begin
   //Приращение по X
   gradX := (cr.gradX * cr.xinc);

   //Вертикальная ПРЯМАЯ линия
   if (gradX = 0) then
   begin
     //Выбор первой точки с которой начинается отрисовка линии
     if (cr.yinc = 1) then y := cr.y0 else y := cr.y1;

     //Цикл по высоте линии
     for i := 1 to (cr.H - lp) do
     begin
       //Целочисленный Z
       z := Round(fZ);
       //Точка
       ZPixel32(x, y, z, dColor);
       //Приращение Y
       y := (y + cr.yinc);
       //Приращение Z
       fZ := (fZ + gradZ);
     end;
   end
   else
   //НЕ прямая вертикальная линия
   begin
     //Приращение по X
     fX := x;

     //Цикл по высоте линии
     for i := 1 to (cr.H - lp) do
     begin
       //Точка
       ZPixel32(x, y, z, dColor);
       //Приращение X
       fX := (fX + gradX);
       //Приращение Y
       y := (y + cr.yinc);
       //Приращение Z
       fZ := (fZ + gradZ);
       //Целочисленный X
       x := Round(fX);
       //Целочисленный Z
       z := Round(fZ);
     end;
   end;
 end;
end;