type
 TResReader = class(TReader)
 public
   procedure ReadPrefix(var Flags: TFilerFlags; var AChildPos: Integer); override;
 end;

procedure TResReader.ReadPrefix(var Flags: TFilerFlags; var AChildPos: Integer);
begin
 inherited ReadPrefix(Flags, AChildPos);
 Include(Flags, ffInherited);
end;

function SetResourceInstance(const NewInstance: Longint): Longint;
var
 CurModule: PLibModule;
begin
 Result := 0;

 CurModule := LibModuleList;
 while CurModule <> nil do
 begin
   if CurModule.Instance = HInstance then
   begin
     if CurModule.ResInstance <> CurModule.Instance then
       FreeLibrary(CurModule.ResInstance);
     CurModule.ResInstance := NewInstance;
     Result := NewInstance;
     Exit;
   end;

   CurModule := CurModule.Next;
 end;
end;

function InternalReloadComponentRes(const sResName: string; hInst: THandle; Instance: TComponent): Boolean;
var
 hRsrc: THandle;
 fStream: TResourceStream;
 fReader: TResReader;
begin
 Result := False;

 if hInst = 0 then
   hInst := HInstance;

 hRsrc := FindResource(hInst, PChar(sResName), RT_RCDATA);
 if hRsrc <> 0 then
 begin
   fStream := TResourceStream.Create(hInst, sResName, RT_RCDATA);
   try
     fReader := TResReader.Create(fStream, 4096);
     try
       fReader.ReadRootComponent(Instance);
     finally
       fReader.Free;
     end;
   finally
     fStream.Free;
   end;

   Result := True;
 end;
end;