TSoapData = TDictionary<string, OleVariant>;
 TSoapDataList = TObjectList<TSoapData>;

 TFWSharePoint = class
 strict private type
   TSharePointAPIType = (atWebs, atLists, atCopy);
 strict private const
   HTTPPrefix = 'http://';
   URL_PREFIX = '%s/_vti_bin/';
   APITypeStrings: array [TSharePointAPIType] of string = (
     HTTPPrefix + URL_PREFIX + 'Webs.asmx',
     HTTPPrefix + URL_PREFIX + 'Lists.asmx',
     HTTPPrefix + URL_PREFIX + 'Copy.asmx'
   );
   procedure SetUrl(const Value: string);
 strict private
   FUrl, FUserName, FPassword: string;
 protected
   function GetRIO: THTTPRIO;
   function GetUrlString(const Path: string; APIType: TSharePointAPIType): string;
 public
   function GetWebSiteList: TSoapDataList;
   function GetLibraryList(const SharePointSrvAddr: string): TSoapDataList;
   function GetItemsList(const SharePointSrvAddr, ListName, Folder: string): TSoapDataList;
   property SharePointURL: string read FUrl write SetUrl;
   property UserName: string read FUserName write FUserName;
   property Password: string read FPassword write FPassword;
 end;

implementation

type
 TExtractURLAction = (eaLeaveOnlyURL, eaTrimLastSlash);
 TExtractURLActions = set of TExtractURLAction;

function ExtractURL(URL: string; Actions: TExtractURLActions): string;
var
 HttpPos, Len: Integer;
begin
 URL := StringReplace(URL, '\', '/', [rfReplaceAll]);
 HttpPos := Pos('http://', URL);
 if HttpPos > 0 then
   Delete(Url, HttpPos, 7);
 Result := URL;
 if eaLeaveOnlyURL in Actions then
 begin
   Result := Copy(Url, 1, Pos('/', Url) - 1);
   if Result = '' then
     Result := URL;
 end;
 if eaTrimLastSlash in Actions then
 begin
   Len := Length(Result);
   while Result[Len] = '\' do
   begin
     Dec(Len);
     SetLength(Result, Len);
     if Len = 0 then Exit;
   end;
 end;
end;

function FillSoapData(Value: IXMLNode): TSoapData;
var
 I: Integer;
 Done: Boolean;
begin
 Done := False;
 Result := TSoapData.Create;
 try
   for I := 0 to Value.AttributeNodes.Count - 1 do
     Result.Add(Value.AttributeNodes[I].NodeName, Value.AttributeNodes[I].NodeValue);
   Done := True;
 finally
   if not Done then
     FreeAndNil(Result);
 end;
end;

function FillWebSoapData(Value: IXMLNode): TSoapData;
begin
 Result := FillSoapData(Value);
 if Result <> nil then
   Result.Add('_Url', Result.Items['Url']);
end;

function FillLibSoapData(Value: IXMLNode; const Path: string): TSoapData;
begin
 Result := FillSoapData(Value);
 if Result <> nil then
   Result.Add('_Url', Path);
end;

function TFWSharePoint.GetLibraryList(const SharePointSrvAddr: string): TSoapDataList;
var
 RealPath: string;
 RIO: THTTPRIO;
 Soap: ListsSoap;
 XMLData: TXMLData;
 I: Integer;
 Data: TSoapData;
 s: TStringList;
begin
 Result := nil;
 RIO := GetRIO;
 try
   RealPath := ExtractURL(SharePointSrvAddr, [eaTrimLastSlash]);
   RealPath := GetUrlString(RealPath, atLists);
   Soap := GetListsSoap(False, RealPath, RIO);
   if Soap = nil then Exit;
   XMLData := Soap.GetListCollection;
   try
     if XMLData.XMLNode.ChildNodes.Count = 0 then Exit;
     Result := TSoapDataList.Create;
     for I := 0 to XMLData.XMLNode.ChildNodes.Count - 1 do
     begin
       Data := FillLibSoapData(XMLData.XMLNode.ChildNodes[I], SharePointSrvAddr);
       if Data <> nil then
         Result.Add(Data);
     end;
   finally
     XMLData.Free;
   end;
 finally
   if Soap = nil then
     RIO.Free;
 end;
end;

function TFWSharePoint.GetRIO: THTTPRIO;
begin
 Result := THTTPRIO.Create(nil);
 Result.HTTPWebNode.UserName := UserName;
 Result.HTTPWebNode.Password := Password;
end;

function TFWSharePoint.GetUrlString(const Path: string;
 APIType: TSharePointAPIType): string;
begin
 Result := Format(APITypeStrings[APIType], [Path]);
end;

function TFWSharePoint.GetWebSiteList: TSoapDataList;
var
 RIO: THTTPRIO;
 Soap: WebsSoap;
 XMLData: TXMLData;
 I: Integer;
 Data: TSoapData;
 RealPath: string;
begin
 Result := nil;
 RIO := GetRIO;
 try
   RealPath := GetUrlString(SharePointURL, atWebs);
   Soap := GetWebsSoap(False, RealPath, RIO);
   if Soap = nil then Exit;
   Result := TSoapDataList.Create;
   Data := TSoapData.Create;
   Data.Add('Title', 'SharePoint сервер');
   Data.Add('Url', HTTPPrefix + SharePointURL);
   Data.Add('_Url', HTTPPrefix + SharePointURL);
   Result.Add(Data);
   XMLData := Soap.GetWebCollection;
   try
     if XMLData.XMLNode.ChildNodes.Count = 0 then Exit;
     for I := 0 to XMLData.XMLNode.ChildNodes.Count - 1 do
     begin
       Data := FillWebSoapData(XMLData.XMLNode.ChildNodes[I]);
       if Data <> nil then
         Result.Add(Data);
     end;
   finally
     XMLData.Free;
   end;
 finally
   if Soap = nil then
     RIO.Free;
 end;
end;

procedure TFWSharePoint.SetUrl(const Value: string);
begin
 FUrl := ExtractURL(Value, [eaLeaveOnlyURL, eaTrimLastSlash]);
end;