ClientDataSet.DisableControls;
try
 // Добавляем в него 100500 записей;
finally
 ClientDataSet.EnableControls;
end;  

unit Unit30;

interface

uses
 Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
 Dialogs, DB, DBClient, StdCtrls;

type
 TForm30 = class(TForm)
   btnInitCDS: TButton;
   CDS: TClientDataSet;
   btnAdd1000: TButton;
   btnAdd10000: TButton;
   btnAdd100000: TButton;
   lblResult: TLabel;
   btnAdd1000000: TButton;
   procedure btnInitCDSClick(Sender: TObject);
   procedure btnAdd1000Click(Sender: TObject);
   procedure btnAdd10000Click(Sender: TObject);
   procedure btnAdd100000Click(Sender: TObject);
   procedure btnAdd1000000Click(Sender: TObject);
 private
   procedure InitCDS;
   procedure AddNRecords(Value: Integer);
   procedure UpdateResultLabel(tc: Cardinal);
 public
   { Public declarations }
 end;

var
 Form30: TForm30;

implementation

{$R *.dfm}

{ TForm30 }

procedure TForm30.AddNRecords(Value: Integer);
var
 tc: Cardinal;
 i: Integer;
begin
 Screen.Cursor := crHourGlass;
 try
   tc := GetTickCount;
   try
     CDS.DisableControls;
     try
       for i := 1 to Value do
       begin
         CDS.Append;
         try
           CDS.FieldByName('ID').AsInteger := i;
           CDS.FieldByName('Caption').AsString := 'AAAA';
         finally
           CDS.Post;
         end;
       end;
     finally
       CDS.EnableControls;
     end;
   finally
     UpdateResultLabel(GetTickCount - tc);
   end;
 finally
   Screen.Cursor := crDefault;
 end;
end;

procedure TForm30.btnAdd1000000Click(Sender: TObject);
begin
 AddNRecords(1000000);
end;

procedure TForm30.btnAdd100000Click(Sender: TObject);
begin
 AddNRecords(100000);
end;

procedure TForm30.btnAdd10000Click(Sender: TObject);
begin
 AddNRecords(10000);
end;

procedure TForm30.btnAdd1000Click(Sender: TObject);
begin
 AddNRecords(1000);
end;

procedure TForm30.btnInitCDSClick(Sender: TObject);
begin
 InitCDS;
end;

procedure TForm30.InitCDS;
begin
 try
   if CDS.Active then
   begin
     CDS.EmptyDataSet;
     CDS.Close;
   end;

   CDS.FieldDefs.Clear;
   CDS.FieldDefs.Add('ID', ftInteger);
   CDS.FieldDefs.Add('Caption', ftString, 30);
   CDS.CreateDataSet;

 finally
   UpdateResultLabel(0);
 end;
end;

procedure TForm30.UpdateResultLabel(tc: Cardinal);
begin
 lblResult.Caption := Format('RecordCount: %d; TotalTime: %d', [CDS.RecordCount, tc]);
end;

end.