program CmdDefSckt;

{$APPTYPE CONSOLE}

uses
 SysUtils,ScktComp,WinSock;

type
 TServerClientThreadEx=class(TServerClientThread)
 private
   Buf:string;
 protected
   procedure ClientExecute; override;
   function WaitForData(Timeout: Longint): Boolean;
   function RecvLn:string;
   procedure SendLn(const Str:string);
   procedure ProcessCmd(const CmdStr:string);
 public
 end;

function TServerClientThreadEx.WaitForData(Timeout: Longint): Boolean;
var
 FDSet: TFDSet;
 TimeVal: TTimeVal;
begin
 TimeVal.tv_sec := Timeout div 1000;
 TimeVal.tv_usec := (Timeout mod 1000) * 1000;
 FD_ZERO(FDSet);
 FD_SET(ClientSocket.SocketHandle, FDSet);
 Result := select(0, @FDSet, nil, nil, @TimeVal) > 0;
end;

function TServerClientThreadEx.RecvLn:string;
var i:integer;
begin
 while ClientSocket.Connected do
 begin
   if not WaitForData(30000) then raise Exception.Create('Protocol: timeout');
   Buf:=Buf+ClientSocket.ReceiveText;
   if length(Buf)>256 then raise Exception.Create('Protocol: long string');
   i:=pos(#13#10,Buf);
   if i>0 then
   begin
     result:=copy(Buf,1,i-1);
     delete(Buf,1,i+1);
     break;
   end;
 end;
end;

procedure TServerClientThreadEx.SendLn(const Str:string);
begin
 ClientSocket.SendText(Str);
 ClientSocket.SendText(#13#10);
end;

procedure TServerClientThreadEx.ProcessCmd(const CmdStr: string);
begin
 if CmdStr='?' then
   SendLn('reboot');
end;

procedure TServerClientThreadEx.ClientExecute;
var CmdStr:string;
begin
 try
   while (not Terminated) and (ClientSocket.Connected) do
   begin
     CmdStr:=RecvLn;
     if length(CmdStr)>0 then
     begin
       writeln('ProcessCmd ',ClientSocket.RemoteAddress,':',ClientSocket.RemotePort,'- ',CmdStr);
       ProcessCmd(CmdStr);
     end;
   end;
 except
   on e: exception do
     writeln('Error: '+e.Message);
 end;
end;

procedure GetThread(Self:TObject;Sender: TObject;ClientSocket: TServerClientWinSocket; var SocketThread: TServerClientThread);
begin
 writeln('GetThreadEvent ',ClientSocket.RemoteAddress,':',ClientSocket.RemotePort);
 SocketThread:=TServerClientThreadEx.Create(false,ClientSocket);
end;

function Proc2Method(Code, Data: Pointer):TMethod;
begin
 result.Code:=Code;
 result.Data:=Data;
end;

var Server:TServerSocket;
begin
Server:=TServerSocket.Create(nil);
try
  Server.ServerType:=stThreadBlocking;
  Server.Port:=19;
  Server.OnGetThread:=TGetThreadEvent(Proc2Method(@GetThread,Server));
  Server.Open;
  while Server.Active do Sleep(100);
finally
  Server.Free;
end;
end.

telnet 127.0.0.1 19
reboot