type
 TProtectedObject = class;

 // Интерфейс доступа к защищенному полю X
 IMyInterface = interface
 ['{9963190E-2137-4247-8CDA-EBFAB63D960A}']
   function GetX: Integer;
 end;

 // Класс, реализующий интерфейс IMyInterface у защищаемого класса TProtectedObject
 TIntfImpl = class(TAggregatedObject, IMyInterface)
 private
   FController: TProtectedObject;
   function GetX: Integer;
 public
   constructor Create(const Controller: TProtectedObject);
 end;

 // Защищаемый класс. Поле X доступно лишь избранным :)
 TProtectedObject = class(TObject, IInterface, IMyInterface)
 private
   X: Integer;
   FAllowAccess: Boolean;
   FIntfImpl: TIntfImpl;
   function GetIntfImpl: IMyInterface;
   // IInterface
   function QueryInterface(const IID: TGUID; out Obj): HResult; stdcall;
   function _AddRef: Integer; stdcall;
   function _Release: Integer; stdcall;
   // IMyInterface
   // Теперь клиент, запросив интерфейс IMyInterface, не пройдет мимо нашего
   // геттера :)
   property IntfImpl: IMyInterface read GetIntfImpl implements IMyInterface;
 public
   constructor Create;
   destructor Destroy; override;
 end;

 // Класс, у которого мы будем просить доступ
 TSecurityClass = class
 public
   class function QueryAccess(Client: TObject; Server: TProtectedObject): IMyInterface;
 end;

implementation

{ TProtectedObject }

function TProtectedObject._AddRef: Integer;
begin
 Result := -1;
end;

function TProtectedObject._Release: Integer;
begin
 Result := -1;
end;

function TProtectedObject.QueryInterface(const IID: TGUID;
 out Obj): HResult;
begin
 if GetInterface(IID, Obj) then
   Result := 0
 else
   Result := E_NOINTERFACE;
end;

function TProtectedObject.GetIntfImpl: IMyInterface;
begin
 if FAllowAccess then
   Result := FIntfImpl
 else
   Result := nil;
end;

constructor TProtectedObject.Create;
begin
 inherited Create;
 FIntfImpl := TIntfImpl.Create(Self);
end;

destructor TProtectedObject.Destroy;
begin
 FIntfImpl.Free;
 inherited Destroy;
end;

{ TIntfImpl }

constructor TIntfImpl.Create(const Controller: TProtectedObject);
begin
 inherited Create(Controller as IInterface);
 FController := Controller;
end;

function TIntfImpl.GetX: Integer;
begin
 Result := FController.X;
end;

{ TSecurityClass }

class function TSecurityClass.QueryAccess(Client: TObject;
 Server: TProtectedObject): IMyInterface;
begin
 Result := nil;
 if <класс клиента является дружественным> then begin
   Server.FAllowAccess := True;
   try
     Result := Server as IMyInterface;
   finally
     Server.FAllowAccess := False;
   end;
 end;
end;

function TProtectedObject.GetIntfImpl: IMyInterface;
begin
if FAllowAccess then
  Result := FIntfImpl
else
  Result := nil; // Тут на самом деле лучше кинуть исключение InvalidTypecast
end;