procedure CMMouseEnter(var Message: TMessage); message CM_MOUSEENTER;
procedure CMMouseLeave(var Message: TMessage); message CM_MOUSELEAVE;
procedure Paint; override;

FCurrentImage: TPicture;

var
 Save: Boolean;
begin
 if csDesigning in ComponentState then
   with inherited Canvas do
   begin
     Pen.Style := psDash;
     Brush.Style := bsClear;
     Rectangle(0, 0, Width, Height);
   end;
 {Save := FDrawing;
 FDrawing := True;}
 try
   with inherited Canvas do
     StretchDraw(DestRect, CurrentImage.Graphic);
 finally
   {FDrawing := Save; }
 end;
end;

TMyButtoState = (mbsUp, mbsHot, mbsDown, mbsDisabled);

private
 fImages: array[TMyButtoState] of TPicture;
property ImageHot: TPicture index mbsHot read GetImage write SetImage;

unit HSFlatImageButton;

interface
uses
 Messages, Classes, Graphics, Controls;

type
 THSButtonState = (hsbsUp, hsbsDown, hsbsHover, hsbsDisabled);
 THSFlatImageButton = class(TGraphicControl)
 private
   FImages: array[THSButtonState] of TBitmap;
   FState: THSButtonState;
   procedure SetState(const Value: THSButtonState);
   function GetImage(const Index: THSButtonState): TBitmap;
   procedure SetImage(const Index: THSButtonState; const Value: TBitmap);
   function GetDisabledImage: TBitmap;
   function GetDownImage: TBitmap;
   function GetHoverImage: TBitmap;
   function GetUpImage: TBitmap;
   procedure SetDisabledImage(const Value: TBitmap);
   procedure SetDownImage(const Value: TBitmap);
   procedure SetHoverImage(const Value: TBitmap);
   procedure SetUpImage(const Value: TBitmap);
 protected
   procedure Paint; override;
   procedure CMMouseEnter (var Message: TMessage); message CM_MOUSEENTER;
   procedure CMMouseLeave (var Message: TMessage); message CM_MOUSELEAVE;
   procedure MouseDown(Button: TMouseButton;
     Shift: TShiftState; X, Y: Integer); override;
   procedure MouseUp(Button: TMouseButton;
     Shift: TShiftState; X, Y: Integer); override;
 public
   constructor Create (AOwner: TComponent); override;
   destructor Destroy; override;
   //for test purposes only
   property State: THSButtonState read FState write SetState;
   property UpImage: TBitmap read GetUpImage write SetUpImage;
   property DownImage: TBitmap read GetDownImage write SetDownImage;
   property HoverImage: TBitmap read GetHoverImage write SetHoverImage;
   property DisabledImage: TBitmap read GetDisabledImage write SetDisabledImage;
   property OnClick;
 end;

implementation

{ THSFlatImageButton }

procedure THSFlatImageButton.CMMouseEnter(var Message: TMessage);
begin
 if Enabled then
   State := hsbsHover;
end;

procedure THSFlatImageButton.CMMouseLeave(var Message: TMessage);
begin
 inherited;
 if Enabled then
   State := hsbsUp;
end;

constructor THSFlatImageButton.Create(AOwner: TComponent);
var
 I: THSButtonState;
begin
 inherited;
 Height := 16;
 Width := 16;
 ControlStyle := ControlStyle + [csReplicatable];
 FState := hsbsUp;
 for I := Low(THSButtonState) to High(THSButtonState) do
 begin
   FImages[I] := TBitmap.Create;
   FImages[I].Height := 16;
   FImages[I].Width := 16;
 end;
end;

destructor THSFlatImageButton.Destroy;
var
 I: THSButtonState;
begin
 for I := Low(THSButtonState) to High(THSButtonState) do
   FImages[I].Free;
 inherited;
end;

function THSFlatImageButton.GetDisabledImage: TBitmap;
begin
 Result := GetImage(hsbsDisabled);
end;

function THSFlatImageButton.GetDownImage: TBitmap;
begin
 Result := GetImage(hsbsDown);
end;

function THSFlatImageButton.GetHoverImage: TBitmap;
begin
 Result := GetImage(hsbsHover);
end;

function THSFlatImageButton.GetImage(const Index: THSButtonState): TBitmap;
begin
 Result := FImages[Index];
end;

function THSFlatImageButton.GetUpImage: TBitmap;
begin
 Result := GetImage(hsbsUp);
end;

procedure THSFlatImageButton.MouseDown(Button: TMouseButton; Shift: TShiftState;
 X, Y: Integer);
begin
 inherited;
 if Enabled then
   State := hsbsDown;
end;

procedure THSFlatImageButton.MouseUp(Button: TMouseButton; Shift: TShiftState;
 X, Y: Integer);
begin
 inherited;
 if Enabled then
   State := hsbsUp;
end;

procedure THSFlatImageButton.Paint;
begin
 Canvas.StretchDraw(ClientRect, FImages[FState]);
end;

procedure THSFlatImageButton.SetDisabledImage(const Value: TBitmap);
begin
 SetImage(hsbsDisabled, Value);
end;

procedure THSFlatImageButton.SetDownImage(const Value: TBitmap);
begin
 SetImage(hsbsDown, Value);
end;

procedure THSFlatImageButton.SetHoverImage(const Value: TBitmap);
begin
 SetImage(hsbsHover, Value);
end;

procedure THSFlatImageButton.SetImage(const Index: THSButtonState;
 const Value: TBitmap);
begin
 FImages[Index].Assign(Value);
 if FState = Index then
   Invalidate;
end;

procedure THSFlatImageButton.SetState(const Value: THSButtonState);
begin
 if FState <> Value then
 begin
   FState := Value;
   Invalidate;
 end;
end;

procedure THSFlatImageButton.SetUpImage(const Value: TBitmap);
begin
 SetImage(hsbsUp, Value);
end;

end.

TButtonGlyph

if Enabled then State := XXX;

procedure THSFlatImageButton.SetState(Value: THSButtonState);
begin
 if not Enabled then Value := hsbsDisabled;
 if fState = Value then Exit;
 fState := Value;
 Invalidate;
end;