Вот, собственно, программка:

unit main;

interface
uses
 Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
 Dialogs, StdCtrls;

type
 TForm1 = class(TForm)
   ListBox1: TListBox;
   Button1: TButton;
   Button2: TButton;
   procedure Button1Click(Sender: TObject);
   procedure FormCreate(Sender: TObject);
   procedure Button2Click(Sender: TObject);
 private
   procedure RefreshWindowList;
 end;

var
 Form1: TForm1;

implementation
uses
 HSHookUtils;

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
begin
 RefreshWindowList;
end;

function EnumWindowProc (Wnd: HWND; Param: LPARAM): Integer; stdcall;
var
 AClassName: array[0..255] of char;
 AStyle: DWORD;
begin
 GetClassName(Wnd, AClassName, SizeOf(AClassName));
 AStyle := GetClassLong(Wnd, GCL_STYLE);
 with TForm1(Param) do
   ListBox1.Items.AddObject(Format('%s (%.8x)', [AClassName, AStyle]),
     TObject(Wnd));
 Result := 1;
end;

procedure TForm1.Button2Click(Sender: TObject);
const
 GOStatus: array[Boolean] of string = ('Failed', 'Success');
var
 Wnd: HWND;
 ADC: HDC;
 Bmp: HBITMAP;
 Info: TagBITMAP;
 Success: Boolean;
 BmInfoStr: string;
begin
 if ListBox1.ItemIndex <> -1 then
 begin
   Wnd := HWND(ListBox1.Items.Objects[ListBox1.ItemIndex]);
   if IsWindow(Wnd) then
   begin
     ADC := GetWindowDC(Wnd);
     try
       Bmp := GetCurrentObject(ADC, OBJ_BITMAP);
       Success := GetObject(Bmp, SizeOf(Info), @Info) <> 0;
       if Success then
         BmInfoStr := Format('%d (%d x %d)', [Info.bmType, Info.bmWidth,
           Info.bmHeight])
       else
         BmInfoStr := 'No info';
       ShowMessageFmt('%.8x = %s (%s) %s', [Integer(Bmp), DecodeGDIHandle(Bmp),
         GOStatus[Success], BMInfoStr]);
     finally
       ReleaseDC(Wnd, ADC);
     end;
   end;
 end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
 RefreshWindowList;
end;

procedure TForm1.RefreshWindowList;
begin
 ListBox1.Clear;
 EnumWindows(@EnumWindowProc, LPARAM(Self));
end;

end.

unit HSHookUtils;

interface

function DecodeGDIHandle (const AHandle: Cardinal): string;
 
implementation
uses
  SysUtils;

function DecodeGDIHandle (const AHandle : Cardinal) : String;
var
 StockObject : Boolean;
 ObjectType,
 Index : Integer;
 ObjectTypeName : String;
begin
 if (AHandle = 0) then begin
   Result := 'NULL';
   Exit;
 end;
 StockObject := (AHandle AND $800000) <> 0;
 ObjectType  := (AHandle SHR 16) AND $7F;
 Index := LOWORD(AHandle);
 case ObjectType of
 1:
   ObjectTypeName := 'HDC';
 4:
   ObjectTypeName := 'HRGN';
 5:
   ObjectTypeName := 'HBITMAP';
 8:
   ObjectTypeName := 'HPALETTE';
 $0A:
   ObjectTypeName := 'HFONT';
 $10:
   ObjectTypeName := 'HBRUSH';
 $21:
   ObjectTypeName := 'HENHMETAFILE';
 $30:
   ObjectTypeName := 'HPEN';
 $50:
   ObjectTypeName := 'HEXTPEN';
 else
   ObjectTypeName := '*ERROR*'+Format('%.2x', [ObjectType]);
 end;
 if StockObject then
   ObjectTypeName := 'S_'+ObjectTypeName;
 Result := Format('%s(%.4x)', [ObjectTypeName, Index]);
end;

end.