unit CheckGroupBox;

interface

uses
 Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
 StdCtrls;

type
 TCGBCheckBox = class(TCustomCheckBox)
 published
   property AllowGrayed;
   property Color;
   property Ctl3D;
   property Enabled;
   property ShowHint;
   property State;
   property OnEnter;
   property OnExit;
   property OnKeyDown;
   property OnKeyPress;
   property OnKeyUp;
   property OnMouseDown;
   property OnMouseMove;
   property OnMouseUp;
 end;

 TCheckCustomGroupBox = class(TCustomGroupBox)
 private
   FCGBCheckBox: TCGBCheckBox;
   FOnCheckBoxClick: TNotifyEvent;
   function GetAlignment: TLeftRight;
   procedure SetAlignment(Value: TLeftRight);
   function GetCaption: TCaption;
   procedure SetCaption(Value: TCaption);
   procedure AdjustCheckBounds;
   function GetChecked: boolean;
   procedure SetChecked(Value: boolean);
   procedure CMFontChanged(var Message: TMessage); message CM_FONTCHANGED;
 protected
   procedure SetEnabled(Value: Boolean); override;
   procedure CheckBoxClick(Sender: TObject); virtual;
   procedure CreateWnd; override;
 public
   constructor Create(AOwner: TComponent); override;
   destructor Destroy; override;
   property CGBCheckBox: TCGBCheckBox read FCGBCheckBox write FCGBCheckBox;
 published
   property BoxAlignment: TLeftRight read GetAlignment write SetAlignment;
   property Caption: TCaption read GetCaption write SetCaption;
   property Checked: boolean read GetChecked write SetChecked;
   property OnCheckBoxClick: TNotifyEvent read FOnCheckBoxClick write FOnCheckBoxClick;
 end;

 TCheckGroupBox = class(TCheckCustomGroupBox)
 published
   property Align;
   property Anchors;
   property Caption;
   property Color;
   property Ctl3D;
   property DragCursor;
   property DragMode;
   property Enabled;
   property Font;
   property ParentColor;
   property ParentCtl3D;
   property ParentFont;
   property ParentShowHint;
   property PopupMenu;
   property ShowHint;
   property TabOrder;
   property TabStop;
   property Visible;
   property OnClick;
   property OnDblClick;
   property OnDragDrop;
   property OnDragOver;
   property OnEndDrag;
   property OnEnter;
   property OnExit;
   property OnMouseDown;
   property OnMouseMove;
   property OnMouseUp;
   property OnStartDrag;
 end;

const
 BOXWITH = 19;

procedure Register;

implementation

procedure Register;
begin
 RegisterComponents('Standard', [TCheckGroupBox]);
end;

constructor TCheckCustomGroupBox.Create(AOwner: TComponent);
begin
 inherited Create(AOwner);
 FCGBCheckBox := TCGBCheckBox.Create(Self);
 with FCGBCheckBox do
   begin
     Parent := Self;
     OnClick := CheckBoxClick;
     Checked := true;
     Left := 6;
     Width := 18;
     inherited Top := 0;
     Caption := '';
   end;
end;

destructor TCheckCustomGroupBox.Destroy;
begin
 FCGBCheckBox.Free;
 inherited Destroy;
end;

procedure TCheckCustomGroupBox.CreateWnd;
begin
 inherited;
 if Caption = '' then
   inherited Text := '';
end;

function TCheckCustomGroupBox.GetAlignment: TLeftRight;
begin
 Result := FCGBCheckBox.Alignment;
end;

procedure TCheckCustomGroupBox.SetAlignment(Value: TLeftRight);
begin
 FCGBCheckBox.Alignment := Value;
end;

function TCheckCustomGroupBox.GetCaption: TCaption;
begin
 Result := FCGBCheckBox.Caption;
end;

procedure TCheckCustomGroupBox.SetCaption(Value: TCaption);
begin
 if (FCGBCheckBox.Left + Canvas.TextWidth(Value) + BOXWITH) < Width then
   begin
     FCGBCheckBox.Caption := Value;
     AdjustCheckBounds;
   end;
end;

procedure TCheckCustomGroupBox.SetEnabled(Value: Boolean);
var
 i: integer;
begin
 inherited;

 if not Value then
   begin
     for i := 0 to ControlCount - 1 do
       Controls[i].Enabled := false;
   end;

 if Value then
   begin
     for i := 0 to ControlCount - 1 do
       begin
         if Controls[i] is TCGBCheckBox then
           begin
             Controls[i].Enabled := true;
             Continue;
           end;
         Controls[i].Enabled := FCGBCheckBox.Checked;
       end;
   end;
end;

procedure TCheckCustomGroupBox.CMFontChanged(var Message: TMessage);
begin
 inherited;
 Canvas.Font := Self.Font;
 FCGBCheckBox.Height := Canvas.TextHeight('ZZ');
 FCGBCheckBox.Top := 0;
 AdjustCheckBounds;
end;

procedure TCheckCustomGroupBox.AdjustCheckBounds;
const
 WordWraps: array[Boolean] of Word = (0, DT_WORDBREAK);
begin
 FCGBCheckBox.Width := BOXWITH + Canvas.TextWidth(FCGBCheckBox.Caption) + 2;
 FCGBCheckBox.Repaint;
end;

function TCheckCustomGroupBox.GetChecked: boolean;
begin
 Result := FCGBCheckBox.Checked;
end;

procedure TCheckCustomGroupBox.SetChecked(Value: boolean);
begin
 FCGBCheckBox.Checked := Value;
 CheckBoxClick(nil);
end;

procedure TCheckCustomGroupBox.CheckBoxClick(Sender: TObject);
var
 i: integer;
begin
 inherited Click;
 for i := 0 to ControlCount - 1 do
   begin
     if Controls[i] is TCGBCheckBox then
       Continue;
     Controls[i].Enabled := FCGBCheckBox.Checked;
   end;
 if Assigned(FOnCheckBoxClick) then FOnCheckBoxClick(Self);
end;

end.

procedure TCheckCustomGroupBox.SetChecked(Value: boolean);
begin
FCGBCheckBox.Checked := Value;
if Enabled then
 CheckBoxClick(nil);
end;

procedure TCheckCustomGroupBox.SetChecked(Value: boolean);
begin
if FCGBCheckBox.Checked <> Value then begin
  FCGBCheckBox.Checked := Value;
  CheckBoxClick(self); //nil не желательно..
end;
end;

procedure TCheckCustomGroupBox.CheckBoxClick(Sender: TObject);
begin
inherited Click;
SetEnabled(FCGBCheckBox.Checked);
if Assigned(FOnCheckBoxClick) then FOnCheckBoxClick(Self);
end;

unit Unit1;
interface
uses
 Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
 Dialogs, Grids, StdCtrls;

type
 TForm1 = class(TForm)
   GroupBox1: TGroupBox;
   CheckBox1: TCheckBox;
   CheckBox2: TCheckBox;
   Edit1: TEdit;
   Button1: TButton;
   procedure CheckBox2Click(Sender: TObject);
   procedure CheckBox1Click(Sender: TObject);
 private
   { Private declarations }
 public
   { Public declarations }
 end;

var
 Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.CheckBox2Click(Sender: TObject);
begin
 GroupBox1.Enabled:=CheckBox2.Checked;
 CheckBox1.Enabled:=GroupBox1.Enabled;
 CheckBox1Click(Sender);
end;

procedure TForm1.CheckBox1Click(Sender: TObject);
var N: Integer;
begin
 for N := 0 to GroupBox1.ControlCount-1 do
   if GroupBox1.Controls[N]<>CheckBox1 then GroupBox1.Controls[N].Enabled:=CheckBox1.Checked and GroupBox1.Enabled;
end;

end.

object Form1: TForm1
 Left = 192
 Top = 114
 Width = 307
 Height = 206
 Caption = 'Form1'
 Color = clBtnFace
 Font.Charset = DEFAULT_CHARSET
 Font.Color = clWindowText
 Font.Height = -11
 Font.Name = 'MS Sans Serif'
 Font.Style = []
 OldCreateOrder = False
 PixelsPerInch = 96
 TextHeight = 13
 object GroupBox1: TGroupBox
   Left = 8
   Top = 8
   Width = 185
   Height = 105
   Caption = '  '
   TabOrder = 0
   object CheckBox1: TCheckBox
     Left = 13
     Top = -2
     Width = 81
     Height = 17
     Caption = 'CheckBox1'
     Checked = True
     State = cbChecked
     TabOrder = 0
     OnClick = CheckBox1Click
   end
   object Edit1: TEdit
     Left = 16
     Top = 28
     Width = 121
     Height = 21
     TabOrder = 1
     Text = 'Edit1'
   end
   object Button1: TButton
     Left = 32
     Top = 60
     Width = 75
     Height = 25
     Caption = 'Button1'
     TabOrder = 2
   end
 end
 object CheckBox2: TCheckBox
   Left = 16
   Top = 128
   Width = 97
   Height = 17
   Caption = 'CheckBox2'
   Checked = True
   State = cbChecked
   TabOrder = 1
   OnClick = CheckBox2Click
 end
end

procedure TCheckCustomGroupBox.SetEnabled(Value: Boolean);
begin
if Enabled<>Value then begin
 inherited;
 FCGBCheckBox.Enabled:=Enabled;
 CheckBoxClick(self);
end;
end;

procedure TCheckCustomGroupBox.CheckBoxClick(Sender: TObject);
var
i: integer;
begin
inherited Click; //незнаю.... вот это вызовет метод Click предка твоего компонента, а не чекбокса в нем
for i := 0 to ControlCount-1 do
  if Controls[i]<>FCGBCheckBox then Controls[i].Enabled:=FCGBCheckBox.Checked and Enabled;
if Assigned(FOnCheckBoxClick) then FOnCheckBoxClick(Self);
end;